一行代码设置TForm颜色的前世今生

procedure TForm1.Button4Click(Sender: TObject);
begin
  Self.Color := clRed;
end;

procedure TControl.SetColor(Value: TColor);
begin
  if FColor <> Value then
  begin
    FColor := Value;
    FParentColor := False;
    Perform(CM_COLORCHANGED, 0, 0); // 第一个消息
  end;
end;

procedure TCustomForm.CMColorChanged(var Message: TMessage);
begin
  inherited;
  if FCanvas <> nil then FCanvas.Brush.Color := Color; // 说到底，还是通过FCanvas.Brush起作用，类属性Color只是表象
end;

procedure TWinControl.CMColorChanged(var Message: TMessage);
begin
  inherited;
  FBrush.Color := FColor;
  NotifyControls(CM_PARENTCOLORCHANGED); // 第二个消息，组建消息并传播，通知子控件，但没有任何子控件响应
end;

procedure TControl.CMColorChanged(var Message: TMessage);
begin
  Invalidate;
end;

procedure TWinControl.Invalidate;
begin
  // 注意，第二个参数即WParam是0，即要求API使自己失效，而不是仅仅做一个通知作用。
  Perform(CM_INVALIDATE, 0, 0); // 第三个消息
end;

procedure TWinControl.CMInvalidate(var Message: TMessage);
var
  I: Integer;
begin
  if HandleAllocated then
  begin
    if Parent <> nil then
      Parent.Perform(CM_INVALIDATE, 1, 0); // 第四个消息，递归，先通知父类。Form1的Parent是Application，它没有响应。
    if Message.WParam = 0 then
    begin
      // API，第二个参数为NULL的话，则重画整个客户区；第三个参数TRUE则背景重绘。
      InvalidateRect(FHandle, nil, not (csOpaque in ControlStyle)); // 总算初步达到目的，使Form1失效，后面还要自绘
      { Invalidate child windows which use the parentbackground when themed }
      if ThemeServices.ThemesEnabled then
        for I := 0 to ControlCount - 1 do
          if csParentBackground in Controls[I].ControlStyle then // important
            Controls[I].Invalidate;
    end;
  end;
end;